|
|
(@@InPutString @@InPutInteger)
[@main]
#IF
equal A1 1
#SAY
<行会名称：/SCOLOR=249><$STR(A109)>\
<竞标时间：/SCOLOR=250><$STR(A110)>\
<行会掌门：/SCOLOR=253><$STR(A121)>\
<行会公告：/SCOLOR=254><$STR(A119)>\
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━\
<本行会现在公开向全服招贤纳士，欢迎各路英雄豪杰加入到本行会/SCOLOR=250>\
→[<加入该行会/@加入>]←最低等级要求为<$STR(G108)>级\
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━\
【<我要竞标/@我也要竞标>】 【<管理选项/@竞标台管理>】
#ELSESAY
<行会名称：/SCOLOR=249><$STR(A109)>\
<竞标时间：/SCOLOR=250><$STR(A110)>\
<行会掌门：/SCOLOR=253><$STR(A121)>\
<行会公告：/SCOLOR=254><$STR(A119)>\
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━\
<我可以帮你实现自动收人、离线收人；就算掌门人不在线，您的/SCOLOR=250>\
<行会照样能招收新人，试试吧!/SCOLOR=250> <注意:每天凌晨0点清空竞标数据!/SCOLOR=249>\
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━\
【<我要竞标/@我也要竞标>】 【<管理选项/SCOLOR=249>】
[@我也要竞标]
<每个星期一凌晨0点将清除所有竞标信息!原始竞标价格20元宝!/SCOLOR=254>\
<竞标方式:采用元宝竞标，只要你给出的价格高于竞标价格，你/SCOLOR=253>\
<的行会就可以中标，直到下一位竞争对手出现./SCOLOR=250>\
┏━━━━━━━━━━━━━━━━━━━━━━━━━━━┓ \
<【竞标行会】/SCOLOR=250><$STR(A109)>\
<【竞标价格】/SCOLOR=250><$STR(G107)><元宝/SCOLOR=249>\
<【竞标时间】/SCOLOR=250><$STR(A110)>\
┗━━━━━━━━━━━━━━━━━━━━━━━━━━━┛ \
【<我要竞标/@竞标开始>】<←只有行会掌门人才可以参与竞标/SCOLOR=249> 【<返回首页/@main>】
[@竞标开始]
#if
ISGUILDMASTER
#act
goto @竞标开始2
#elseact
inc N5 1111111111
messagebox 对不起，你不是行会掌门
[@竞标开始2]
#if
equal a109 <$GUILDNAME>
#act
messagebox 错误，你所在的行会已经是中标行会！
break
#elsesay
\ \
→当前竞标价格: <$STR(G107)> 元宝\ \
\
→<输入竞标价格/@@InPutInteger70> (只能为高于当前竞标价格的整数)\ \
→<返回/@我也要竞标>
[@InPutInteger70]
#if
large n70 <$STR(G107)>
#act
goto @竞标3
#elseact
messagebox 对不起，你的出价太低！
[@竞标3]
#if
CHECKGAMEGOLD < <$STR(n70)>
#act
messagebox 对不起，你没有那么多元宝！
#elsesay
你给出的价格为<$STR(n70)>元宝,请填写完整以下信息：\ \
→<输入招收会员的最低等级要求/@@InPutInteger71> (10-50)必须大于10小于50\
→最低等级:<$STR(n71)>级\
→<输入一段简短公告/@@InPutString11> (在石板上显示)\
→行会公告:<$STR(s11)>\ \
→<提交信息/@竞标4>
[@InPutInteger71]
#if
large n71 10
small n71 50
#act
messagebox 设定成功，加入你的行会的最低等级要求是<$STR(n71)>级！
goto @竞标3
#elseact
messagebox 请输入一个10－50间的整数,必须大于10小于50！
goto @竞标3
[@InPutString11]
#act
goto @竞标3
[@竞标4]
#If
small n71 10
#act
messagebox 请设定招收会员的最低等级要求！
goto @竞标3
#elsesay
以下是你的全部信息，点击确定提交信息：\
行会名称：<$GUILDNAME>\
行会掌门：<$USERNAME>\
竞标价格：<$STR(n70)>元宝\
竞标时间：<$DATETIME>\
等级要求：<$STR(n71)>级\
公告内容：<$STR(s11)>\ \
→【<确定提交信息/@竞标5>】 【<返回重新填写/@竞标开始>】
[@竞标5]
#if
CHECKGAMEGOLD > <$STR(n70)>
large n70 <$STR(G107)>
#act
GAMEGOLD - <$STR(n70)>
mov a109 <$GUILDNAME>
mov g107 <$STR(n70)>
mov a110 <$DATETIME>
mov g108 <$STR(n71)>
mov a119 <$STR(s11)>
mov a121 <$USERNAME>
mov g109 0
mov g110 0
MOV A1 1
SENDMSG 0 【系统】：<$USERNAME>为自己的行会竞标成功！
close
#elseact
SENDMSG 7 【系统】：条件不够
goto @main
[@加入]
#if
equal a109 暂无
#act
SENDMSG 6 [非法操作]
goto @main
break
#if
equal g109 1
#act
messagebox 对不起，本行会暂时不收人
break
#IF
HAVEGUILD
#ACT
MESSAGEBOX [失败]:您已经有行会了。无法申请!\请先退出你当前的行会！
break
#if
CHECKLEVELEX < <$STR(g108)>
#act
messagebox 等级不够！
break
#if
#act
AddGuildMember <$STR(A109)> <$USERNAME>
messagebox 恭喜你已经成功加入到<$STR(A109)>
[@竞标台管理]
#if
ISGUILDMASTER
equal a109 <$GUILDNAME>
#act
goto @竞标台管理2
#elseact
SENDMSG 5 [只有本行会掌门才可以进行管理]
goto @main
[@竞标台管理2]
#if
equal g109 0
#act
mov s1 <开启/SCOLOR=250>
#if
equal g109 1
#act
mov s1 <关闭>
#if
equal g110 0
#act
mov s2 <允许/SCOLOR=250>
#if
equal g110 1
#act
mov s2 <禁止>
#if
#say
→当前行会公告内容:<更改/@@InPutString12>\
→<$STR(a119)>\
→当前收人等级要求:<更改/@@InPutInteger72>\
→<$STR(G108)>级\
→当前行会收人状态:<更改/@gg1>\
→<$STR(s1)>\ \
→<返回/@main>
[@gg1]
#if
equal g109 0
#act
mov g109 1
messagebox 行会收人状态→关闭
goto @竞标台管理
break
#if
equal g109 1
#act
mov g109 0
messagebox 行会收人状态→开放
goto @竞标台管理
break
[@InPutInteger72]
#if
large n72 10
small n72 50
#act
mov g108 <$STR(n72)>
messagebox 修改成功，加入你的行会的最低等级要求是<$STR(n72)>级！
goto @竞标台管理
#elseact
messagebox 请输入一个10－50间的整数,必须大于10小于50！
goto @竞标台管理
[@InPutString12]
#if
equal s12
#act
messagebox 非法字符
#elseact
mov a119 <$STR(s12)>
messagebox 修改成功
goto @竞标台管理
|
|
发表于 2022-4-22 14:29:30
